Windows Batch Backup Script

ich stand vor kurzem vor dem problem geplanter backups in ner arztpraxis.

auslöser war nämlich, daß in der praxis nur eine person weiß, wie ein backup gemacht wird (via gekaufter software), diese person aber nicht jeden tag da ist, um zu sichern. und prompt kam es zum headcrash und zum datenverlust (3 tage).

ziel:
wenns geht kostenfreie backuplösung
am besten 2x täglich
benutzer (rezeption) soll nichts dazu tun müssen

naheliegend wären ja die geplanten tasks, aber beim aufruf der "Sicherung" (start > programme > zubehör > systemprogramme > Sicherung) muss der benutzer dann doch wieder ran.
ergo: die gute alte batch muß her.

mein script benötigt einmalig (per texteditor; anfang des scripts) das verzeichniss, in dem das backup erstellt werden soll, und den pfad zu einer filterdatei, in der steht, welche verzeichnisse gesichert werden sollen (wird mit "Sicherung" erstellt, indem man im reiter "Sichern" die verzeichnisse anwählt und dann die auswahl via Auswahl > Auswahl speichern ... in einer .bks datei speichert).

nach aufruf des scritpts passiert folgendes:
das script erstellt bei bedarf das backup verzeichniss und wechselt dorthin.
dann wird geprüft, ob ein ordner 'morgens' existiert, bei bedarf erstellt und ein backup inselbigem erstellt.
gibts den ordner 'morgens' schon, wird ein verzeichniss 'abends' gesucht. existiert es nicht, wird es erstellt, hineingewechselt und darin das backup erstellt.
gibts den order 'abends' schon, haben wir (theoretisch) schon zwei backups gemacht und können aufhören.

und das ganze in batch:


@echo off
rem *********************************** Start VARIABLEN
set BACKUPDIR=d:\backup
set FILTER=d:\filter.bks
rem *********************************** Ende VARIABLEN

rem *********************************** Start ANFANGSBILDSCHIRM
cls
echo Willkommen zu Ihrem lieblings Backup Programm:
echo ==============================================
echo.
echo.
rem *********************************** Ende ANFANGSBILDSCHIRM

rem *********************************** Start VERZEICHNISSE
echo Suche Verzeichniss "%BACKUPDIR%" ...
IF not exist %BACKUPDIR%. (
echo Verzeichniss existiert noch nicht. Wird erstellt ...
mkdir %BACKUPDIR%
)

echo Wechseln zu %BACKUPDIR% ...
cd %BACKUPDIR%

echo Suche Verzeichniss "%DATE%" ...
set DATEDIR=%DATE%
IF not exist %DATEDIR%. (
echo Verzeichniss existiert noch nicht. Wird erstellt ...
mkdir %DATEDIR%
)

echo Wechseln in Verzeichniss %DATEDIR% ...
cd %DATEDIR%

echo Suche Verzeichniss "morgens" ...
IF not exist morgens. (
echo Verzeichniss ecistiert noch nicht. Wird erstellt ...
mkdir morgens
echo Wechseln in Verzeichniss "morgens" ...
cd morgens
) ELSE (
echo Heute morgen wurde schon gesichert.
echo Suche Verzeichniss "abends" ...
IF not exist abends. (
echo Verzeichniss nicht gefunden. Wird erstellt ...
mkdir abends
echo Wechseln in Verzeichniss "abends" ...
cd abends
) ELSE (
echo Heute wurde bereits zwei mal gesichert. Gut so!
goto ende
)
)
rem *********************************** Ende VERZEICHNISSE

rem *********************************** Start BACKUP
echo Erstelle BACKUP in %CD% ...
ntbackup.exe backup "@%FILTER%" /v:yes /r:no /rs:no /hc:off /m normal /j "Sicherung" /l:n /f "%CD%\Sicherung_%DATE%.bkf"
echo Geschafft.
rem *********************************** Ende BACKUP

:ENDE
pause

(link)

jetzt muß nur noch via 'geplante Tasks' ein job erstellt werden, der täglich (werktags) morgens und abends einmal unser script aufruft und wir habens geschafft (=